gdドキュメント0.8.0

データベースを使う

English | 日本語

やることリストを保存する小さなスクリプトを作りながら、データベースの使い方を順に説明します。最初は設定の要らないSQLiteを使い、最後にPostgreSQLへ切り替えます。

1. 開いて、表を作る

todo.gdに保存します。

func main() -> int, Err:
    var db := GD.database.client()
    db.open({"driver": "sqlite", "path": "user://todo.sqlite3"})?
    db.query("CREATE TABLE IF NOT EXISTS todos(id INTEGER PRIMARY KEY, title TEXT NOT NULL UNIQUE, done INTEGER NOT NULL DEFAULT 0)")?
    db.close()
    return 0
gd todo.gd

2. 追加して、読む

db.close()の前に次の行を足します。

    db.query("INSERT INTO todos(title) VALUES($1)", ["牛乳を買う"])?
    var got := db.query("SELECT id, title, done FROM todos ORDER BY id")?
    for row in got.rows:
        print(row.id, " ", row.title)

SQL文には$1、$2と書き、入れる値は2番目の引数の配列で渡します。値を文字列としてSQL文へつなげないでください。$1で渡せば、どんな文字が入っていても値として扱われます。

結果のrowsは行の配列で、各行は列名で読める辞書です。

3. 読み方を選ぶ

読みたいもの使う関数
結果の全部query
先頭の1行query_row
大量の行を1行ずつquery_rows

query_rowは、行が無いとErr.NOT_FOUNDを返します。「無い」を失敗にしたくないときは、自分で見分けます。

func title_of(db: GDDatabaseClient, id: int) -> String, Err:
    var row, e := db.query_row("SELECT title FROM todos WHERE id=$1", [id])
    if e and e.kind == Err.NOT_FOUND:
        return "(なし)"
    if e:
        return "", e
    return row.title

query_rowsは、結果をメモリへためずに1行ずつ読みます。next()がfalseになったらerr()を確かめ、最後にclose()します。

func print_titles(db: GDDatabaseClient) -> int, Err:
    var rows := db.query_rows("SELECT title FROM todos ORDER BY id")?
    while rows.next():
        print(rows.scan()?.title)
    if rows.err() != null:
        return 1, rows.err()
    rows.close()
    return 0

4. 同じものを二重に登録しない

titleにはUNIQUEを付けたので、同じ題名を2回入れると失敗します。失敗の種類はe.infoのviolationで分かります。

func add(db: GDDatabaseClient, title: String) -> bool, Err:
    var _made, e := db.query("INSERT INTO todos(title) VALUES($1)", [title])
    if e and e.info.get("violation") == "duplicate":
        return false
    if e:
        return false, e
    return true

violationはduplicate(重複)、not_null(必須の値が無い)、foreign_key(参照先が無い)のどれかです。

5. 複数の変更をまとめて確定する

途中で失敗したら全部を取り消したい変更は、transactionにまとめます。渡した関数が成功を返せば確定し、Errを返せば取り消します。

func finish_all(db: GDDatabaseClient) -> int, Err:
    return db.transaction(func(tx: GDDatabaseTx) -> int, Err:
        tx.query("UPDATE todos SET done=1")?
        var left := tx.query("SELECT count(*) AS n FROM todos WHERE done=0")?
        return left.rows[0].n
    )

関数の中では、dbではなく渡されたtxでSQLを実行します。db.query()はこのまとまりに入りません。

6. PostgreSQLへ切り替える

変えるのはopenに渡す設定だけです。queryやtransactionの書き方はそのまま使えます。

func open_postgres() -> GDDatabaseClient, Err:
    var db := GD.database.client()
    db.open({
        "driver": "postgres",
        "host": "127.0.0.1",
        "database": "app",
        "user": "app",
        "password": GD.cli.env("PGPASSWORD", ""),
    })?
    return db

7. Webサーバーから使う

リクエストを処理する関数では、GD.async.with_context_pairにreq.contextを渡します。相手が接続を切ったときに、待っている問い合わせをキャンセルできます。

func list_todos(req: GDWebRequest, db: GDDatabaseClient) -> Variant, Err:
    return await GD.async.with_context_pair(req.context, db.query_async("SELECT id, title FROM todos"))

キャンセルの仕組みは非同期処理とキャンセルで説明しています。